
**Constructing Quadratic Surface with Nine Points in GeoGebra**

Tõnu Tõnso Tallinn University, lecturer, [tonu@tlu.ee](file:///C:\quadratic_surface_ggb\tonu@tlu.ee)

Rando Tõnso, University of Tartu, IT student, [rt.peakonto@gmail.com](mailto:rt.peakonto@gmail.com)

In GeoGebra there is a tool for conic passing through 5 points:

**Equation of quadric determined by 9 points**

Five points in the plane uniquely determine an equation for a conic section. The general equation of a conic section is a quadratic equation in two variables involving six coefficients:

The coefficients in (1) cannot all be zero. If it were known a priori which coefficient is non-zero, then each term can be divided by it to reduce the number of unknown coefficients to five. Thus, five points ,,, and are sufficient to uniquely determine a conic.

An alternate way to formulate the solution to (1) is to observe that the five additional equations must be satisfied:

Equations (1) and (2) form a homogeneous system of six equations in six unknowns.

Since the solution vector must be non zero, the determinant of the coefficient matrix must be zero, i.e.

This is *equation for conic passing through 5 points*. The above formula is well-known and can be found in web encyclopedia MathWorld (mathworld.wolfram.com/ConicSection.html).

The general equation for a quadratic surface (also called quadric) is a quadratic equation in three variables involving ten coefficients:

The coefficients in (4) cannot all be zero. If it were known a priori which coefficient is non-zero, then each term can be divided by it to reduce the number of unknown coefficients to nine. Thus, nine points are sufficient to uniquely determine a quadric.

An alternate way to formulate the solution to (4) is to observe that the nine additional equations must be satisfied:

Equations (4) and (5) form a homogeneous system of ten equations in ten unknowns.

Since the solution vector must be nonzero, the determinant of the coefficient matrix must be zero, i.e.

This is *equation for quadric passing through 9 points*. Nine points from the quadratic surface determine a quadric’s equation.

In the course of writing the present paper two interesting questions arose:

1. Do arbitrary 5 points on plane uniquely determine the equation of a conic section?
2. Do arbitrary 9 points in space uniquely determine the equation of a second order surface?

The answer to both questions is negative.

Assume we have given 5 points on the plane such that arbitrary 4 points of them are not located on a straight line. Then there exists exactly one conic section, passing through all 5 points.

Assume we have given 9 points in space such that *k* points are not located on one plane while remaining 9-*k* points lie on the straight line. Then there exists exactly one second order surface, passing through all 9 points.

Both statements are given in analytic geometry textbook [Lumiste, Ariva, Analüütiline Geomeetria, p 397-398], first of them is also proved there.

The 10th order determinant is a sum of up to =3628800 terms, each term being a product of nine numbers and one monomial from the first row. Computing the 10th order determinant, simplifying the obtained expression and creating a 3D image of the 2nd order surface corresponding to this complicated expression is not an easy task. Some computer algebra systems can do it. Our interest was to examine if GeoGebra can do it. The answer is yes; however, certain problems appeared as well.

# GeoGebra solution

Open algebra view, CAS view and 3D graphics view. You will also need input bar.

Create nine points. These will be named to . An easy way to create points with round coordinates is to use the input bar. For example, one may write the following lines to the input bar.  
P\_1=(0,0,0)  
P\_2=(2,4,6)  
P\_3=(0,2,1)  
P\_4=(0,4,4)  
P\_5=(2,0,2)  
P\_6=(4,0,8)  
P\_7=(-2,-2,3)  
P\_8=(-2,-4,6)  
P\_9=(2,2,3)

Create a list containing all points previously defined.  
Points = {P\_1, P\_2, P\_3, P\_4, P\_5, P\_6, P\_7, P\_8, P\_9}

Later it will be easier if we have all x, y and z coordinates in their own list.   
The first step is to convert Points (which is a list of points) into a list of lists of numbers. In mathematics on would write it as  
  
In GeoGebra we do it like this:  
Coordinates = Zip({x(P), y(P), z(P)}, P, Points)  
 We call the Zip function with three arguments. The first argument is an expression containing identifier P. The second argument is the identifier that we wish to substitute (currently P). The third argument is a list of values. Each value will be put in place of P in the expression and all the resulting values of the expressions will be put into a list and that is the result of a Zip function.   
GeoGebra treats a list of lists as a matrix. Our matrix should have 9 rows and 3 columns. Then we transpose our matrix as follows  
TransposedCoordiantes = Transpose(Coordinates).  
and we get a list of x’s, y’s and z’s. We assign those lists to separate variables.  
Xs = TransposedCoordinates(1)  
Ys = TransposedCoordinates(2)  
Zs = TransposedCoordinates(3)

Our next steps will be in CAS view. CAS view allows us to use symbolic computation, for example we can use unknown variables in expressions without evaluating them. Syntax of CAS view is a bit different. In CAS view we use := for assignment instead of =.

Our next task is to make the following matrix.

Note that the first row contains unknown variables and the other rows contain only numeric values.

Let’s make the first row.

FirstRow := {x^2,y^2,z^2,x\*y,x\*z,y\*z,x,y,z,1}

Then let’s make the other rows.

OtherRows := Zip({X^2,Y^2,Z^2,X\*Y,X\*Z,Y\*Z,X,Y,Z,1},X,Xs,Y,Ys,Z,Zs)

Here the Zip function gets 7 arguments, the first one is the expression containing identifiers to be substituted and the other arguments come in pairs. The first argument in a pair is the identifier (like X) and the second argument is the list of values (like Xs). There are three pairs. When doing the substitution GeoGebra will first use values of Xs(1), Ys(1), Zs(1) then Xs(2), Ys(2), Zs(2) and so on.

Then we will join the FirstRow and the OtherRows to get a matrix.

AllRows := Join({FirstRow}, OtherRows)

The Join function takes two lists as arguments. To join FirstRow with OtherRows vertically we put FirstRow into a matrix.

Then we find the determinant of AllRows matrix.

Det := Determinant(AllRows)

The resulting polynomial may contain large coefficients. To simplify the polynomial, we first find the greatest common divisor (gcd) of its coefficients:

GreatestDivisor := GCD(Coefficients(Det))

After that we divide Det by GreatestDivisor, equalize the resulting expression with 0 and assign the equation to variable named Quadric.

Quadric := Det/GreatestDivisor=0

If GeoGebra does not show the surface in 3D graphics view click on the white circle below the CAS row number of Quadric.

There are 17 different quadrics: 5 imaginary quadrics (*imaginary ellipsoid, imaginary cone (point), imaginary elliptic cylinder,* pair of *imaginary intersecting planes (line), two imaginary parallel planes*), 3 reducible surfaces (*pair of coincident planes, pair of intersecting planes, pair of parallel planes*) and 4 degenerative surfaces (*elliptic cylinder, hyperbolic cylinder, parabolic cylinder, elliptic cone*). Remaining 5 quadrics are nondegenerative noncylindrical surfaces (*ellipsoid, elliptic paraboloid, hyperboloid of one sheet, hyperboloid of two sheets, hyperbolic paraboloid*).

## References

1. Lumiste, Ü and Ariva, K. Analüütiline Geomeetria,Tallinn, Valgus, pp. 397-398, 1973.

2. [Weisstein, E. W.](http://mathworld.wolfram.com/about/author.html)  *Conic Section*. From [MathWorld](http://mathworld.wolfram.com/) -- A Wolfram Web Resource. http://mathworld.wolfram.com/ConicSection.html [19. 09. 2019]